Adding python3.10, podman

dev-libs/libcbor/Manifest

@@ -0,0 +1,2 @@
+DIST libcbor-0.8.0.tar.gz 267044 BLAKE2B e8548e7351984ebdcbeb5f13a7ca35412c3f3f05e2a44a5438d57b90bdcdc51f5265953163106f90ade911a96af665956ebeba7ed1c48cf207acf6d683af5606 SHA512 694d2d3a78d80072f96e0afb73590ca1f3572e41d2117330ef4313ed06271743b048d3ba3259c6ffe9a802d5e441379d0e54787d1d42fed08dc81ac4f06c6dbc
+EBUILD libcbor-0.8.0.ebuild 1412 BLAKE2B 37fa9e5d256c785c8d93ece1151a40c018fc23b9e5b542499a2608416adc4ff83e0f9dfa34b2d326a19028c5931afbe805e3b6d2b191bf365a293ff7cca0659e SHA512 f8e656cff6deed12c074f3d2de804ba5f0aa08b34a49a3e473e1ad0f58a99ed8a42b310919b3af83073f2adb2635aae1e8bea67c44b3986731d1be81e87ee1f4

dev-libs/libcbor/libcbor-0.8.0.ebuild

@@ -0,0 +1,69 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+inherit python-any-r1 cmake-utils
+
+DESCRIPTION="CBOR protocol implementation for C and others"
+HOMEPAGE="https://github.com/pjk/libcbor"
+SRC_URI="https://github.com/PJK/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~s390 sparc x86"
+IUSE="+custom-alloc doc test"
+
+BDEPEND="
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+			dev-python/breathe[${PYTHON_USEDEP}]
+		')
+	)
+	test? ( dev-util/cmocka )
+"
+
+RESTRICT="!test? ( test )"
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+
+python_check_deps() {
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+		has_version "dev-python/breathe[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local -a mycmakeargs=(
+		-DCMAKE_BUILD_TYPE=Release
+		-DCBOR_CUSTOM_ALLOC=$(usex custom-alloc 'ON' 'OFF')
+		-DWITH_TESTS=$(usex test 'ON' 'OFF')
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc; then
+		pushd doc >/dev/null || die
+		emake html man
+		popd >/dev/null || die
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use doc; then
+		dodoc -r doc/build/html
+		doman doc/build/man/*
+	fi
+}

dev-libs/libfido2/Manifest

@@ -0,0 +1,2 @@
+DIST libfido2-1.7.0.tar.gz 517426 BLAKE2B c7ad55d1402808ad12dc999b0ec67161a5fe82dfeaeed362c35f4183144af9bd2771c1e3318a731db46fd8fc21ccd0737024b72c8dd3c754e34625118817742f SHA512 f40d394883d909e9e3ea3308b32f7ca31a882c709e11b3b143ed5734d16b0c244d4932effe06965d566776b03d152b1fc280e73cdfeeb81b65d8414042af19fe
+EBUILD libfido2-1.7.0.ebuild 902 BLAKE2B 982a9fab49585bb15b46e3e0ded878de6279fb87f64e27529a1fc67948e51a33d9da7daef230807936f8ce1811253c2bbe3f89652010ee7ff419cd1ce9c126eb SHA512 f9824e7f0b4556891aa7a92e143f71d58854833a8f654d92dbdb8d62273082d99770e869788b3a8828d305663a9f0347f2a0cd6dd8bc93a42e2497a352a5ec16

dev-libs/libfido2/libfido2-1.7.0.ebuild

@@ -0,0 +1,53 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake udev linux-info
+
+DESCRIPTION="Provides library functionality for FIDO 2.0"
+HOMEPAGE="https://github.com/Yubico/libfido2"
+SRC_URI="https://github.com/Yubico/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0/1"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~s390 sparc x86"
+IUSE="nfc +static-libs"
+
+DEPEND="
+	dev-libs/libcbor:=
+	dev-libs/openssl:0=
+	sys-libs/zlib:0=
+	virtual/libudev:=
+"
+
+RDEPEND="
+	${DEPEND}
+"
+
+pkg_pretend() {
+	CONFIG_CHECK="
+		~USB_HID
+		~HIDRAW
+	"
+
+	check_extra_config
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DNFC_LINUX="$(usex nfc)"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if ! use static-libs; then
+		rm -f "${ED}/$(get_libdir)"/*.a || die
+	fi
+
+	udev_newrules udev/70-u2f.rules 70-libfido2-u2f.rules
+}
+