Adding libhandy 1.0.X

dev-libs/libhandy/Manifest

@@ -0,0 +1,2 @@
+DIST libhandy-1.0.1.tar.gz 483165 BLAKE2B b378b97fda6ce237f79cc826c66cdede5f335c94ce465e83fa5d732e9ccbfab9a71d255eeba3c80c6fdaeb17effe64d1bf723ecdcc857765e2634ec93fb7e54b SHA512 f83773960f74d0513b753d16623aaa70dba1c22539ea2f54646469bca9c9a30153927f14b4c5e2430c1c4aba70bf89773b0921aca614be7a24bfc9c9dfb845d7
+EBUILD libhandy-1.0.1.ebuild 1253 BLAKE2B 373a09090770b3cd406001db9188542e698bdca781a386818377447cad3ca7d6a337929c1a2e9ce36eb12ac0b5690410fc971bffe5d79c4b47bbafee4a9ae8ec SHA512 8ae5aea0324cc3192efa24435ee650989367c57fdb08512eaa6839104214e1808c42fca3b2785acf2b2d644a4a3d5c92f75bdc5efca5b0d6122c4845be23fdf3

dev-libs/libhandy/libhandy-1.0.1.ebuild

@@ -0,0 +1,57 @@
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg vala virtualx
+
+DESCRIPTION="Building blocks for modern adaptive GNOME apps"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libhandy"
+SRC_URI="https://gitlab.gnome.org/GNOME/libhandy/-/archive/${PV}/${PN}-${PV}.tar.gz"
+S="${WORKDIR}/${PN}-${PV}"
+
+LICENSE="LGPL-2.1+"
+SLOT="${PV}/1"
+KEYWORDS="*"
+
+IUSE="examples glade gtk-doc +introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.24.12:3[introspection?]
+	glade? ( dev-util/glade:3.10= )
+	introspection? ( >=dev-libs/gobject-introspection-1.62:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofiling=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use test tests)
+		$(meson_use examples)
+		$(meson_feature glade glade_catalog)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}